Conference hydra::amiga_v1

    This sounds REAL good -- I will try the new progs and see if they
    eliminate my upload through TSN failures. Currently, I have no problems
    downloading via TSN, but must avoid TSN and direct dial for any
    uploads because they terminate with handshaking failures. This sounds
    like it could correct it -- I'll let you know.
    
    Question: With this new terminal specifier option, will a VMS ZMODEM
    talk to another VMS ZMODEM? Sounds like it could replace KERMIT
    completely.
    
    Thanks for the change!
    
     -- Keith

    
 >   Question: With this new terminal specifier option, will a VMS ZMODEM
 >   talk to another VMS ZMODEM? Sounds like it could replace KERMIT
 >   completely.
    
    Sure. Except kermit does allow system type commands like DIR and SERVER
    modes, where as the remote end with ZMODEM has to be started to send
    a specific file. ie The local end can't ask the remote end to send a
    specific file.
    
    /Steve.

    What are the best programms running on Amiga and using Zmodem ?
    
    Phil

I use VT100 or VLT

john

    re: .2
    >Sure. Except kermit does allow system type commands like DIR and SERVER
    >modes, where as the remote end with ZMODEM has to be started to send
    >a specific file. ie The local end can't ask the remote end to send a
    >specific file.
    
    ZMODEM, if fully implemented, can do many things on the remote end. I
    can't remember for the life of me exactly what it can do, but I seem to
    recall it being able to create directories and delete files and such.
    Maybe it doesn't have a SERVER mode like Kermit, but I think it can do
    quite a bit.
    
    re: .3
    I generally use JRComm for all my ul/dling. Especially when using
    ZMODEM. I think JRComm's implementation of ZMODEM is the most
    efficient, and utilizes the most options of ZMODEM. And as for 19.2K
    zfers. I had my A3000 25/40 hooked up here at work a few weeks ago
    using rz/sz at 19.2K. I ran into no problems at all. I must have sent
    over 2megs to my Ami in a couple hours. BTW: The autodownload feature
    on JRComm which automatically starts dling a file without typing
    anything on the Ami end made the xfers alot easier and faster.
    
    Bob Pomeroy
    REFINE::POMEROY

    Re: -1
    
    The "automatic download feature" is more of a feature of ZMODEM
    rather than JRCOMM. VLT, VLTjr, and Online!Platinum all have this
    same feature when using Zmodem. I agree -- it makes life a lot easier
    and is why I try to do everythig in ZMODEM.
    

    	I use VLT/VLTjr and the external ZMODEM protocol. I start up
    a VMS batch job and let the sucker download all night.
    
    Keith
    

    
    Re: last few
    
    One thing I would like to see (or understand, if it's "in there") is
    wildcarding, read "sz *.lzh" or somesuch.
    
    On the other hand, does the change have any influence to the current
    need for sz to have it's frame length set to 1024 (sz "l" 1024) and the
    XPRZmodem stuff (I use VLT) to the same size _and_ max 16KB buffer to
    get the whole thing working for files larger 32KB ?
    
    Regards,
    
    <CB>
    

I tried the new SZ.EXE using VLT through TYMNET @2400 baud and I think
it is much better than before. Although I only tried a few small files,
I was able to get a transfer rate nearly equal to a direct dial transfer
which has worked well in the past. The old SZ used to time out a lot and
be much slower than a direct dial. Disclaimer: This was not a scientific
test where I accounted for all of the possible variables - just a pleasant
surprise after I switched to the new SZ.EXE and tried a few DLs.

Dave

    I, too, used the new SZ.EXE last night and it worked like a charm.  I
    used to get quite a few timeouts due to bad lines and had to restart
    the download.  I didn't have to do that last night even though the
    download window in VLTjr gave the "port busy hit ^q to reset" message
    on a couple of files.  I also didn't have to set the "k" flag to
    download in 1k blocks (e.g. "sz -rk filenam").  The one thing I noticed
    is that when I got the "port busy message", which indicated a timeout,
    the message didn't clear from the download window until the next file
    started to transfer so I was unable to see which blocks got errors.  No
    biggie though.  I managed to download >1meg of data without any
    restarts which is a first for me.
    
    mark

    
    
    >One thing I would like to see (or understand, if it's "in there") is
    >wildcarding, read "sz *.lzh" or somesuch.
    
    Here's a command file we use to add to the functionality sz. It allows
    wildcarding and gives some stats on how long the entire transfer will
    take. Read the comments for usage. Be careful not to select to many
    files or the DCL command generated is to long (more than 256 I think)
    and causes a failure. It's still evolving, feel free to clean it up or
    change it to meet your needs.
    
    
    
    
$!
$!      SZ_SEND.COM
$!      November 16th, 1988
$!      Clint Adams (CGOU01::ADAMS)
$!      July 1990 - updated for new zmodem.
$!
$!      Modified, SEP 11th, 1989 - to find expicit paths
$!        as SENDZ DUA1:[x]file.one,dua3:[x]file.two would not
$!        work.
$!      This little command file will let you give VMS Zmodem (aka SZ)
$!      a standard VMS filespec for batch transfers. Define a symbol
$!      like send:==@"this command file" and then type
$!              $ send "filespec"
$!      it will then build a command file with syntax that SZ.EXE 
$!      can deal with. 
$!
$!      If you typed 
$!              $ send [stuff]*.arc,*.zoo
$!      it will select all the .arc's and .zoo's in the directory [stuff]
$!      and build a command file to execute the the transfer.
$!
$!      File specs are limited to only one directory at a time.
$!      The symbol "sz" used by this procedure can be define by
$!                      $ SZ:==$device:[directory]SZ.EXE
$!
$ if p1 .eqs. "" then exit
$! if p2 specified it must be a valid device
$ modem_line = ""
$ if p2 .eqs. "" then goto nop2
$ if f$getdvi("''p2'","exists") 
$   then 
$   modem_line = "-m ''p2'"
$ else
$   write sys$output "No such device ''p2'"
$   exit
$ endif
$nop2:
$ on error then goto error
$ on control_y then goto error
$ on control_c then goto error
$ size=0
$ hours=0
$ minutes=0
$ hours1=0
$ minutes1=0
$ if f$type(sz) .eqs. "" then goto nosz
$ define temp sys$login:
$ dir:=dir/notrail/nohead/vers=1
$ dir/out=temp:send.temp 'p1
$ write sys$output ""
$ write sys$output "Sending the following files with Zmodem.... "
$ write sys$output ""
$ my_def = f$env("default")
$ my_Dev = f$parse(my_def,,,"device")
$ my_dir = f$parse(my_def,,,"directory")
$ open senddata temp:send.temp
$ open/write outtocom temp:doit.com
$ write outtocom "$ sz ''modem_line' -kr-"
$loop:
$ read/end_of_file=doit senddata file
$ name=f$parse(file,,,"name")
$ type=f$parse(file,,,"type")
$ dir=f$parse(file,,,"directory")
$ dev=f$parse(file,,,"device")
$ size=size+f$file_attributes(file,"eof")
$ if (my_dev .eqs. dev) then dev = ""
$ if (my_dir .eqs. dir) .and. (dev .eqs. "") then dir = ""
$ write outtocom " " + dev + dir + name + type + "-"
$ write sys$output  file
$ goto loop
$doit:
$ write sys$output ""
$ write outtocom ""
$ write outtocom "$"
$ write outtocom "$exit"
$ close outtocom
$ if size .eq. 0 then goto nofile
$ bytes=(size*512)
$ baud = "2400"
$ throughput = 224              ! 2400 baud dailup
$ timetotran=bytes/throughput
$ days=timetotran/(3600*24)
$ hours=timetotran/3600
$ minutes=(timetotran- ((days*86400)+(hours*3600)) ) /60
$ seconds=timetotran-( (days*86400)+(hours*3600)+(minutes*60) )
$ curtime=f$time()
$ comptime=f$cvtime("''curtime+''hours':''minutes':''seconds'.00","absolute")
$ write sys$output "Total Bytes:    ''bytes'			Current Time ''curtime'"
$ tstr=f$cvtime("''days' ''hours':''minutes':''seconds'","delta")
$ tstr=tstr-".00"
$ write sys$output "Xmit time  :	''tstr' (''baud' Baud)	Completes at ''comptime'"
$ write sys$output ""
$! curdir=f$directory()
$! set def 'dir
$ @temp:doit.com
$! set def 'curdir
$ if f$logical("senddata") .nes. "" then close senddata
$ if f$logical("outtocom") .nes. "" then close outtocom
$ delete temp:doit.com;*,send.temp;*
$ deassign temp
$ exit
$nofile:
$ write sys$output "No files could be found to match your file specification..."
$ write sys$output ""
$ if f$logical("senddata") .nes. "" then close senddata
$ if f$logical("outtocom") .nes. "" then close outtocom
$ delete temp:doit.com;*,send.temp;*
$ deassign temp
$ exit
$nosz:
$ write sys$output "The symbol SZ is not defined. Please define the symbol with the"
$ write sys$output "command:"
$ write sys$output "                    $ sz:==$device:[directory]SZ.EXE"
$ write sys$output ""
$error:
$ set noon
$ if f$logical("senddata") .nes. "" then close senddata
$ if f$logical("outtocom") .nes. "" then close outtocom
$ delete temp:doit.com;*,send.temp;*
$ deassign temp
$ exit