Conference netcad::hub_mgnt

Do you need the sources to do this?  I am in the process of getting the sources
together so I can attempt a full build on an AXP machine (courtesy of a very
kind gentleman in Atlanta).  But if all that is required is to run the image(s)
through a translator, that would make life very simple.  There are 3 executables
in the kit.  You can get them by extracting them from the latest kit at

	NETCAD::PROJ$706:[NDU.V3.RELEASE.VMS.POST_VMS_V5_5]NDUPLUS010.A

...Roger...

The DCF kit installs just fine on OpenVMS AXP V6.1.  But I suspected it would
since the kit simply provides binary images and release notes that are not
intended to execute on the AXP.  DECndu Plus, however, is another story.  The
existing network kit for OpenVMS does not install on an AXP.  It fails with an
error regarding the NDU$MAIN.EXE file having an incorrect format for the AXP
architecture.  I suspect that the same would be true for the other two .EXE
files in the kit.

I have attempted to translate the images using the DECmigration tool VEST.  The
images seemed to translate OK, I rebuilt the NDU kit with the new images and the
installation went smoothly.  However, upon issuing the DOWNLOAD command the
NDU$MAIN image fails to execute with an "ident mismatch with shareable image"
error.  I have not gone any further with it yet.

...Roger...

$!
$! HUB_LOAD.COM
$!
$! VMS command procedure for loading various DEChub device firmware using
$! DECndu Plus.
$!
$! Authors: Tim Gordon (LEVERS::GORDON) and Roger Gaudet (ROGER::GAUDET).
$!
$! Modified: Jon J. Danzak (PTOJJD::DANZAK) 
$!  (Added parameter driven lists, default images and some minimal error
$!   checks)
$!
$! Modified: Roger Gaudet (ROGER::GAUDET)
$!  (Add 'start' label so when user says "Yes" to "Load another device" the
$!   procedure will display the entire device menu)
$!
$! Arguments:  P1 = Device address of the device to be loaded.
$!
$!                  Notes:
$!
$!                  1) When loading the DECbridge 90 or 90FL, specify the
$!                     MAC address of the bridge.
$!                  2) When loading the DECconcentrator 900MX, specify the
$!                     in-band IP address of the DEChub 900 Multiswitch.
$!
$!             P2 = Firmware image name (include directory spec if the file is
$!                  not in your default directory)
$!
$!             P3 = Optional read_write community string to gain SNMP
$!                  read-write access to the device (if not "public").
$!                  To preserve lowercase, enclose this string in double
$!                  quotes ("").
$!
$!             P4 = Optional slot number of the device (some devices need this
$!                  parameter for a successful load).  The procedure will
$!                  prompt for this argument when needed.
$!
$! Invoke this command procedure as follows:
$!
$! $ @HUB_LOAD <device_address> <firmware_image> [<community_string>] [<slot>]
$!
$! If you omit required parameters, you will be prompted for them.
$!
$ on control_y then goto really_done
$ on warning then goto really_done
$ bell[0,8] = 7
$!
$start:
$!
$! List of images, corresponds to list of names
$!
$defs="DENMA021.SYS;DEWGB310.SYS;DEFBA140.BIN;DEF6X280.BIN;DMHUB310.BIN;"
$defs=defs+"DEFMI110.BIN;DETMI110.BIN;DEFMM110.BIN;DETTM110.BIN;"
$defs=defs+"DETMM110.BIN;Exit"
$!
$! List of names, corresponds to images, ends with Exit
$!
$names="DECagent 90;DECbridge 90, 90FL;DECbridge 900MX;DECconcentrator 900MX;"
$names=names+"DEChub 900 MultiSwitch;DECrepeater 90FS;DECrepeater 90TS;"
$names=names+"DECrepeater 900FP;DECrepeater 900GM;DECrepeater 900TM;Exit"
$!
$!
$! Specify Internet or Ethernet
$!
$addrs="I;E;I;I;I;I;I;I;I;I;Exit"
$
$!
$! Build a list of default images...
$!
$count=0
$def_loop:
$count=count+1
$def'count'=f$extract(0,f$locate(";",defs),defs)	!extract up to semi
$defs=defs-def'count'-";"				!remove from list
$if defs.nes."" then $goto def_loop			!until null
$!
$max=count						!save as max...
$!
$count=0
$name_loop:
$count=count+1
$name'count'=f$extract(0,f$locate(";",names),names)	!extract up to semi
$names=names-name'count'-";"				!remove from list
$if names.nes."" then $goto name_loop			!until null
$!
$count=0
$addr_loop:
$count=count+1
$addr'count'=f$extract(0,f$locate(";",addrs),addrs)	!extract up to semi
$addrs=addrs-addr'count'-";"				!remove from list
$if addrs.nes."" then $goto addr_loop			!until null
$!
$temp=max+1	!zap to pretty print if dangling last on right
$name'temp'=""
$addr'temp'=""
$def'temp'=""
$!
$! Compute maximum line
$!
$temp=max/2
$if (max/2).ne.(max/2)*2 then $temp=(max+1)/2
$!
$! Say hello to the world and list stuff
$!
$show_selection:
$ type sys$input

Select the device to be loaded:

$
$line=0
$line_loop:
$line=line+1
$test=temp+line		!parallel line
$out="                                                       "
$temp1=name'line'
$temp1="''line'.) ''temp1'"
$out[5,f$len(temp1)+5]:="''temp1'"
$temp2=""
$if name'test'.eqs."" then $goto print
$temp2=name'test'
$temp2="''test'.) ''temp2'"
$out[40,f$len(temp1)+40]:="''temp2'"
$print:
$write sys$output out
$if line.lt.temp then $goto line_loop
$!
$write sys$Output " "
$ inquire select "Enter your selection"
$ if select .eqs. "" .or. select .eq. max then goto really_done
$ if select .ge. 1 .and. select .le. max-1 then goto select_ok
$ write sys$output "''bell'"
$ write sys$output "*** Invalid selection.  Please try again."
$ goto show_selection
$!
$select_ok:
$!
$if addr'select'.eqs."E" then temp="Ethernet"
$if addr'select'.eqs."I" then temp="TCP/IP"
$ if p1 .eqs. "" then inquire p1 "Device ''temp' address"
$ if p1 .eqs. "" then goto done
$!
$! Check for a "-" in Ethernet address or "." in Internet address
$! Enet address is also 17 characters long
$!
$if (addr'select'.eqs."E").and.-
    (f$len(p1).eq.17).and.-
    (f$locate("-",p1).ne.f$len(p1)) then $goto get_firmware
$if addr'select'.eqs."I".and.(f$locate(".",p1).ne.f$len(p1)) then $goto
get_firmware
$ write sys$output "''bell'"
$ write sys$output "*** Invalid selection.  Please try again."
$p1=""
$goto select_ok
$
$!
$get_firmware:
$def="MOM$LOAD:"+def'select'
$ if p2 .eqs. "" then inquire p2 "Firmware image (''def')"
$if p2.eqs."" then $p2=def
$write sys$Output "Image will be ''p2'
$ if p2 .eqs. "" then goto done
$!
$ if f$search(p2) .eqs. ""
$ then
$   write sys$output "''bell'"
$   write sys$output "*** Firmware image ''p2' not found!  Please try again."
$   write sys$output ""
$   p2 = ""
$   goto get_firmware
$ endif
$!
$! Don't need to ask for the community string if it's a DECbridge 90 or 90FL
$!
$ if p3 .eqs. "" .and. select .ne. 2
$ then
$   inquire p3 "Community String [public]"
$   if p3 .eqs. "" then p3 = "public"
$ endif
$ pass = "/pass=""''p3'"""
$!
$! Need slot number for DECconcentrator 900MX (MAM-assisted load)
$!
$get_slot:
$ if select .eq. 4 .and. p4 .eqs. ""
$ then
$   inquire p4 "Slot number"
$   if p4 .eqs. "" then goto done
$ endif
$ if p4 .eqs. "" then goto do_load
$ if f$integer(p4) .lt. 1 .or. f$integer(p4) .gt. 8
$ then
$   write sys$output "''bell'"
$   write sys$output "*** Slot ''p4' is out of range (1-8).  Please try again."
$   write sys$output ""
$   p4 = ""
$   goto get_slot
$ endif
$!
$do_load:
$ goto load_'select'
$!
$load_1:	! DECagent 90
$!
$ download load 'p1' 'p2' /force=DECagent 'pass'
$ goto done
$!
$load_2:	! DECbridge 90, 90FL
$!
$ download load 'p1' 'p2' /nomanagement
$ goto done
$!
$load_4:	! DECconcentrator 900MX
$!
$ download load 'p1' 'p2' /module='p4' /force=hubmodule 'pass'
$ goto done
$!
$load_5:	! DEChub 900 MultiSwitch
$!
$ download load 'p1' 'p2' /module=9 /force=hubmanv2 'pass'
$ goto done
$!
$load_3:	! DECbridge 900MX
$load_6:	! DECrepeater 90FS
$load_7:	! DECrepeater 90TS
$load_8:	! DECrepeater 900FP
$load_9:	! DECrepeater 900GM
$load_10:	! DECrepeater 900TM
$!
$ download load 'p1' 'p2' /force=pcommon 'pass'
$ goto done
$!
$done:
$ p1 = ""
$ p2 = ""
$ p3 = ""
$ p4 = ""
$ write sys$output ""
$ inquire /nopunct load_again "Load another device? [Y/<N>] "
$ if load_again then goto start
$really_done:
$ exit

re: .10

>NDU$MAIN image fails to execute with an "ident mismatch with shareable image"
>error.  I have not gone any further with it yet.

I have found the same problem as well. 
NDU plus requires  Fortran V6 (or later) and C++ , otherwise the mismatch
errors occur. NDU$MAIN requires that the following images be activated as well

      VAXCRTL
      LIBRTL
      UVMTHRTL
      LIBRTL 
      CMA$TIS_SHR 
      LIBRTL 
      UVMTHRTL 

This should be corrected or the dependencies documented in the release notes. 

andrew

Andrew,

Thanks for the feedback.  Unfortunately we simply have not done much testing of
NDU on the AXP, nor do we have the resources to do so.  The small amount of
testing I have done has resulted in the posting of note 1368.10.  If making NDU
run on an AXP was as simple as "VESTing" the NDU images, I would build a kit in
a heartbeat and make it available (with the obvious stipulation that the kit is
WYSIWYG).  But as you can see from 1368.10 I have not had much success.

We are currently developing a new application which will be an integral part of
HUBwatch, as well as a standalone DOS/Windows application.  If HUBwatch is
supported on OpenVMS AXP, then this application will run in that environment.  I
do not know the exact details of HUBwatch support regarding OpenVMS AXP.

This is the bottom line regarding the current version of DECndu Plus: there will
be no further development of the product, nor any ports to support other
platforms.  Versions that support OpenVMS VAX and MS-DOS are the only supported
versions today.  The new HUBloader application mentioned above will support all
the platforms supported by HUBwatch V4.0.  If you are not sure about what
platforms this consists of, contact product management.

...Roger...

Roger,

I should have made it clear that I was refering to the VMS kit and not the AXP
kit in .12 . We would expect to get alot of calls at the CSC if the problem 
is not rectified. 

Andrew

Since your note read "RE: .10" and that note has to do with my attempts to get
DECndu running on an AXP I assumed that's what you were referring to.  Sorry.

You didn't mention in your note which version of VMS.  There are two kits for
DECndu Plus on OpenVMS, as indicated in the base note, one for VMS prior to V5.5
and one for V5.5 and later.  Please make sure you have the correct kit.  If you
have the right version, then we'll have to look into it further.

...Roger...

By popular demand ...

There is a series of directories under the NETCAD::PROJ$722:[ONEHUB.RELEASE]
directory, each of which contains the product-specific "stuff" (and more). 
These directories are typically used by manufacturing to copy firmware images,
release notes, etc.  They are maintained by the individual product developers,
so if you are confused about the contents of a specific directory, contact the
developers.  Who are the developers you ask?  Most of them monitor this
notesfile, so you can ask in here.  Here's the list of directories:

            [.DEF6X]     DECconcentrator 900MX
            [.DEFBA]     DECbridge 900MX, DECswitch 900EF
            [.DEFMI]     DECrepeater 90FS
            [.DEFMM]     DECrepeater 900FP
            [.DENMA]     DECagent 90
            [.DERMN]     DECpacketprobe 90
            [.DETMI]     DECrepeater 90TS
            [.DETMM]     DECrepeater 900TM
            [.DETTM]     DECrepeater 900GM
            [.DEWBR]     DECbrouter 90
            [.FIRMWARE]  DEChub Consolidated Firmware Kit
            [.MAM]       DEChub 900 MultiSwitch Hub Manager
            [.WGB]       DECbridge 90, 90FL

In general, the directories are further divided by version, but not always.  You
will have to navigate the directories to find the "latest" if that's what you're
looking for.  And remember that since they are individually maintained, the file
naming conventions will vary.  That's why the consolidated kit was born!

Happy hunting.

...Roger...

re: .15

>Since your note read "RE: .10" and that note has to do with my attempts to get
>DECndu running on an AXP I assumed that's what you were referring to.  Sorry.
>
>You didn't mention in your note which version of VMS.  There are two kits for
>DECndu Plus on OpenVMS, as indicated in the base note, one for VMS prior to V5.5
>and one for V5.5 and later.  Please make sure you have the correct kit.  If you
>have the right version, then we'll have to look into it further.
>
>...Roger...

Sorry, I have been away on leave ...

I was using the SSB kit from NETCAD::PROJ$706:[NDU.V3.RELEASE.VMS.SSB]

I have since checked the post V5.5 and pre V5.5 kits and found that the
NDU$MAIN image have the same dependencies 

andrew

The DEChub Consolidated Firmware Kit V1.1 and DECndu Plus V1.0 are now available
on the November 1994 Consolidated Software Distribution CDROM for OpenVMS VAX.

Both kits are located on DISK #1 in directory [DCF011], which is the kit name
under which the consolidated firmware kit was originally made available. 
However, the CONDIST documentation identifies the version as V3.1 to be
consistent with the version of HUBwatch which the firmware kit supports.

The next version of the DEChub Consolidated Firmware Kit will be V4.0 to match
the corresponding release of HUBwatch.  We will also make sure that the CONDIST
directory is [DCF040] so as to be consistent with accepted naming conventions.

...Roger...