Conference azur::mcc

3567.0. "DECmcc /ULTRIX launching HubWatch in Singapore" by TOOK::FLETCHER () Fri Aug 14 1992 14:10

My name is Robin G. Fletcher from the Networks Applications Group
working with the DECmcc Frameworks group.  I already have written
a script to launch HUBwatch from DECmcc.  I have been waiting on
some problems (small) to be solved with the HUBwatch people, so I can
give the final seal of approval to the script.  

The script (we plan) shall be put onto the HUBwatch distribution kit
and along with directions detailing how to integrate the application
into the DECmcc (v1.2.0) Applications menu.

Below is a draft of the script.  I will supply in a later reply the
final version of this script.

------------------------------draft of script---------------------------------------
#!/bin/csh 
#
#	mcc_hubwatch.csh
#
# Digital Equipment Corporation, 1992.
#
# Software Product Group
# Open Network Systems Engineering 
# Network Management Systems
#
# Description:
#
#  This is C-Shell script to invoke the DEC Hub Watch90 Application for all
#  selected entities on a DECmcc Iconical Map.
#
# Parameters:
#
#   $1 is the name of the Launch Application Datafile
#
# Dependencies:
#   DEC Hub Watch90 Environment variable LNMSHOME points to toplevel directory
#    in which HUBWatch software resides. 
#
#
# Set up some variables.
#
set HUBWATCH_DIR = `printenv LNMSHOME`
if ($HUBWATCH_DIR == "") then
   echo "DEC Hub Watch 90 Application invokation requires"
   echo " LNMSHOME to point to top_level directory."
   exit 1
endif
#
# File containing IP community strings.
#  Format:  IP_address read_community write_community
#
set COMMUNITY_FILE = /etc/community
#
# Get application launch datafile from DECmcc
#
set DATAFILE = $1
if ($DATAFILE == "") then
   echo "No datafile passed.  Exiting"
   exit 1
endif
#
# Get list of selected SNMP entities from launch application datafile.
#
set IPs = `cat $DATAFILE | awk '$1 == "SENTITY:" && $2 == "SNMP" {print $6}'`
set Hosts = `cat $DATAFILE | awk '$1 == "SENTITY:" && $2 == "SNMP" {print $8}'`
#
# If there are NO selected SNMP entities, exit.
#
if ($#IPs == 0) then
   echo "NO SNMP Entities were selected.  Exiting."
   exit 0
endif
#
@ i = 0
#
# Start up DEC HUB Watch for each selected SNMP entity.
#
foreach ip ($IPs)
#
   set host = ($Hosts)
   @ i++
#
#  Get community string for read and write for each IP.
#   If community file does NOT exist, prompt user for
#    information and write it to new file.
  set read_comm = `grep $ip $COMMUNITY_FILE | awk '{print $2}'`
  set write_comm = `grep $ip $COMMUNITY_FILE | awk '{print $3}'`
#
# If EITHER are not found then MUST ask user to enter manually.
#  Because we just don't know for sure which one was mistakenly
#  removed from the file.
#
  while ($read_comm == "")
    echo -n "ENTER read community string for SNMP entity ($ip): "
    set read_comm = $<
  end
#
  if ($write_comm == "") then 
     echo -n "ENTER write community string for SNMP entity ($ip) [unknown]: "
     set ans = $<
     if ($ans != "") set write_comm = $ans
  endif  
#
  grep $ip $COMMUNITY_FILE >> /dev/null
  if ($status == 1) then
     echo "$ip $read_comm $write_comm" >> $COMMUNITY_FILE
  endif       
#
# Invokation depending on availability of write community string.
#  Inform user that when write_community is found in $COMMUNITY_FILE, application
#  will be invoked with write permissions.
#
  if ($write_comm == "") then
     echo "DEC HUB Watch 90 invoked for SNMP entity $ip read-only."
     echo "  If read-write required, edit $COMMUNITY_FILE and ensure entry states "
     echo "    ip_address read_community write_community."
     echo ""
     $HUBWATCH_DIR/DH90_main -a $host -x $ip &
  else 
    $HUBWATCH_DIR/DH90_main -a $host -x $ip -c $write_comm &
  endif
end

sleep 20

exit





 

BTW, the new command line parms to invoke HUBwatch are:

DH90_main -x "ip" -c "community" -a "name" -to "timeout" -rt "retries"

Again,
The script I placed in here is DRAFT.  I am still working with the HUBwatch people
to finalize it.  

ANOTHER modification required on the script...Change the printenv LNMSHOME to
printenv NMS_DIR.

When the final version is ready, I will put it in here....until then, I will
keep putting the changes in here.

Any info on :

	- Hubwatch
	- Hubwatch and DECmcc V1.2 Ultrix (integration functionalities)
	- The functionalities of this launching system and how it can be
	delivered  (requirements...)

Thank you,

Jean-Marie