| RE: 1943.0
> I have read the T1.2 release notes and some other documentation, but
> still can't seem to find anything on auto-discovery. Will this
> function (which is present in ETHERnim) for discovering physical
> addresses on the network be part of DECmcc V1.2 ?
>
> Also, there is no mention of using bridge forwarding databases to
> determine topology. Is this not being done in V1.2?
The DECmcc Extended LAN Management package (version that layers on DECmcc
V1.2), due to enter EFT before the end of the year (at least on VMS),
does some "auto-discovery" and "topology" functions.
1. There will be a Listener detached process that will "learn"
Bridge Addresses on an extended LAN (using Listen-for-SYSID) and
allow registration of the newly found bridges
2. There will be a Bridge Spanning Tree FM which will build a
Map reflecting the Bridge Spanning Tree. The Map will contain
Bridges and Domains between Bridges. Bridge Relationships are
determined by polling individual bridges for Spanning Tree information
3. There will be a FDDI Ring Map FM that will use the FDDI AM to
generate Maps of an FDDI ring (with ALL FDDI stations shown in
their correct position on the ring)
What will NOT be in this package:
1. Ability to auto-discover, ala NMCC/VAX ETHERnim, all Stations on
a LAN (though we're looking at this seriously for the "next" version
after DECmcc V1.2).
2. Ability to automatically place Stations in the correct LAN (e.g.,
THIS station is between THESE TWO BRIDGES). I believe the LAN BU
is looking at including this functionality in a version of the
Bridge Spanning Tree FM after this release.
> I currently use a command procedure for locating a node
> (using physical address) by polling all the bridges to determine the
> line on which the node's address is seen. Works great.
Sounds neat! Can you supply more details on this tool?
Chris
|
| $! MCC_BRIDGE_SEARCH.COM
$!
$! 15-AUG-1991 Dan Hill
$! DISCLAIMER: I spent more time documenting this procedure than I spent
$! writing it, but it does work. You can see the principle
$! and how it can be modified with a few more conditional
$! statements to walk a "cascaded" bridge topology.
$!
$! Utility searches all bridges via the DECmcc BRIDGE AM to determine
$! the line on which a node's physical address has been seen.
$! This procedure was designed to work with DECmcc V1.1.0
$!
$! This procedure accepts a 'p1' input parameter in the hex format
$! of an Ethernet Physical address as found in the bridge forwarding
$! database (e.g., AA-00-04-00-AB-CD or 08-00-2B-1F-2D-3E )
$!
$! From DCL, execute the procedure as follows:
$! $ @MCC_BRIDGE_SEARCH.COM AA-00-04-00-AB-CD
$!
$! This procedure assumes the following bridge topology:
$!
$! --o--- LAN Segment 1
$! | --o--- LAN Segment 2
$! | | --o--- LAN Segment 3
$! A B A
$! .bridge.BRDG01 .bridge.BRDG02 .bridge.BRDG03
$! B A B
$! ----o---o---------------o---------------o--- LAN Segment 4B
$! B
$! .bridge.BRDG04
$! A
$! ----o---o---------------o---------------o--- LAN Segment 4A
$! A B B
$! .bridge.BRDG05 .bridge.BRDG06 .bridge.BRDG07
$! B A A
$! | | --o--- LAN Segment 7
$! | --o--- LAN Segment 6
$! --o--- LAN Segment 5
$!
$!
$! Two ASCII text files are used by this command procedure and contain the
$! names of bridges plus the line number (port A = port 1, port B = port 2)
$! which is connected to the "outer-most" segment. To speed the search,
$! the procedure starts with the center bridge (.bridge.BRDG04) to determine
$! on which port the address_to_search was last seen. This eliminates the
$! need to search the forwarding databases of all bridges.
$! The format of the text files is as follows:
$!
$!MCC_COMMON:MCC_SEG4B_BRDGS.DAT
$!.bridge.BRDG01 1 <---- Note: Be sure to leave out the "$!" in each line
$!.bridge.BRDG02 2
$!.bridge.BRDG03 1
$!
$!MCC_COMMON:MCC_SEG4A_BRDGS.DAT
$!.bridge.BRDG05 2
$!.bridge.BRDG06 1
$!.bridge.BRDG07 1
$!
$!------------------------------------------------------------------------
$ SET NOON
$!
$ On control_y Then Goto FINISHED
$!
$ address_to_search = p1
$!
$!
$! Check the Center Bridge first to see if address is on LAN Segment 4A or 4B
$!
$ bridge_name = ".bridge.BRDG04"
$ port_last_seen = "0"
$!
$ GOSUB FIND_PORT
$!
$!
$ IF port_last_seen .NES. "1" .AND. port_last_seen .NES. "2"
$ THEN
$ WRITE SYS$OUTPUT " "
$ WRITE SYS$OUTPUT ".bridge.BRDG04 Port last seen - "+port_last_seen
$ WRITE SYS$OUTPUT "Address was not seen by .bridge.BRDG04 ..."
$ WRITE SYS$OUTPUT " "
$ GOTO FINISHED
$ ENDIF
$!
$ IF port_last_seen .EQS. "1"
$ THEN BRIDGE_FILE = "MCC_COMMON:MCC_SEG4A_BRDGS.DAT"
$ ENDIF
$!
$ IF port_last_seen .EQS. "2"
$ THEN BRIDGE_FILE = "MCC_COMMON:MCC_SEG4B_BRDGS.DAT"
$ ENDIF
$!
$!
$! Loop through selected OPS or MAINT Bridge File
$!
$ WRITE SYS$OUTPUT "OPENING----------> "+BRIDGE_FILE
$ open/read BDG_FILE 'BRIDGE_FILE'
$LOOP_BDG:
$ read/end_of_file=FINISHED BDG_FILE bdg_name_line
$ bridge_name = f$extract(0,14,bdg_name_line)
$ bridge_seg_line = f$extract(15,1,bdg_name_line)
$!
$ GOSUB FIND_PORT
$!
$ IF (port_last_seen .EQS. bridge_seg_line)
$ THEN
$ GOTO FOUND_THE_ADDRESS
$ ENDIF
$!
$GOTO LOOP_BDG
$!
$!............................................................................
$! Subroutines
$!
$FIND_PORT:
$ DEFINE/USER/NOLOG SYS$OUTPUT BRIDGE_PORT.TMP
$ MAN/ENT SHOW BRIDGE 'bridge_name' FORWARD DATA PHYSICAL -
ENTRY 'address_to_search' ALL STATUS
$!
$ IF F$SEARCH("BRIDGE_PORT.TMP") .EQS. "" THEN EXIT
$!
$ open/read BRIDGE_PORT BRIDGE_PORT.TMP
$ LOOP_TMP:
$ read/end_of_file=END_LOOP_TMP BRIDGE_PORT dataline
$!
$ IF f$extract(30,12,dataline) .eqs. "Last Port = "
$ THEN
$ port_last_seen = f$edit(f$extract(42,1,dataline),"TRIM")
$ WRITE SYS$OUTPUT " "
$ WRITE SYS$OUTPUT bridge_name+" Last Port = "+port_last_seen
$ ENDIF
$!
$ Goto LOOP_TMP
$ END_LOOP_TMP:
$ CLOSE BRIDGE_PORT
$RETURN
$!
$!.............................................................................
$FOUND_THE_ADDRESS:
$ WRITE SYS$OUTPUT "++++++++++++++++++++++++++++++++++++++++++++++++++++++++"
$ WRITE SYS$OUTPUT "Found address "+address_to_search+" on " -
+bridge_name+"'s LAN segment connected to Port "+port_last_seen
$ WRITE SYS$OUTPUT "++++++++++++++++++++++++++++++++++++++++++++++++++++++++"
$!
$!
$FINISHED:
$ write sys$output bdg_name_line
$ DELETE/NOLOG BRIDGE_PORT.TMP;*
$ CLOSE BRIDGE_FILE
$ EXIT
|