Conference bulova::decw_jan-89_to_nov-90

Is this a remote machine (i.e. a non-workstation)?   Perhaps DECW$STARTUP has
not been run?

Burns

        No, this is 3100 that is part of a cluster.
        

I had someone else log into their account on my workstation and the problem did
not exist. If I log into someone else's workstation in my account, the problem 
does not exist. It only happens on my workstation, in my account.

    Probably something in your login.com.  Are you playing with FILE_DEV??
    
    
    Donnna

Also look in SYS$SPECIFIC:[sysmgr],[syslib], and [sysexe] to see if there are
any DECW$ files there.  There may be some log files, but if there are .COM or
.EXE, this may be your problem.

Burns

By narrowing in on the various startups, logins, etc. I isolated the source of
the problem to the following startup file that ran each time I logged onto my
workstation. Eliminating this startup (which goes with a third party product),
the problem is eliminated. However, I don't know exactly what in this file 
causes the problem:

$!
$	Terminal_name	== f$getdvi ("TT","DEVNAM")
$	Terminal_id	== Terminal_name - "_" - ":"
$       decw == f$extract(0,2,Terminal_id) .eqs. "TW"
$ 	terminal_type == ""
$	term_type := 'term_type
$ 	if term_type .eqs. "" then -
		Term_type = f$getdvi ("''Terminal_id':" , "DEVTYPE" )
$	if term_type .eq. 96 then Terminal_type == "VT100"
$	if term_type .eq. 98 then Terminal_type == "VT102"
$!	if term_type .eq. 100 then Terminal_type == "VT125"
$! 	if term_type .eqs. "VDU-VT200" then terminal_type == "VT125"
$ 	if terminal_type .eqs. "" then terminal_type == "VT125" ! assume best
$! 	write sys$output "Terminal type is ''terminal_type'"
$!
$! Set up top line username
$	Username := 'f$extract (0,9,f$getjpi ( "" , "USERNAME" ) )
$	top_line_user_name == USERNAME
$! now centre it in a 16 char field
$	len = f$len(top_line_user_name)
$	sposn = 8 - (len/2)
$	top_line_user_name == "        ''top_line_user_name'        "
$	top_line_user_name == f$extract( sposn,16,top_line_user_name)
$!
$	DEFINE	MIS_mail_file		'terminal_id'MAIL.COM;
$	DEFINE	MIS_DCL_SPAWN_INPUT	'terminal_id':
$	DEFINE	MIS_DCL_SPAWN_OUTPUT	'terminal_id':
$!
$       @acu_disk:[acusys]ADD_LOGICAL -
                    LNM$FILE_DEV LNM$PROCESS_DIRECTORY LNM$ACU_TABLE
$
$!
$! define temp mailbox
$       DEFINE/TABLE=LNM$PROCESS_DIRECTORY LNM$TEMPORARY_MAILBOX LNM$ACU_TABLE
$!
$! and for ERR_error_log procedure
$	DEFINE	MIS_error_logging_file		SYS$OUTPUT
$	DEFINE	MIS_error_AST_logging_file	SYS$OUTPUT
$
$!-----------------------------------------------------------------------------
$       IF "''FIN_file_extension'" .nes. "atf" then -
$	FIN_file_extension	== "alf"	! this provides a mechanism
$						! with FIN to have test forms
$	Form_delay_seconds	== "5"		! time delay for form programs
$!-----------------------------------------------------------------------------
$!
$       regname == f$trnlnm( "ACU_REGNAME", "LNM$ACU_TABLE" )
$       if regname .nes. "" then goto l_regname_ok
$       write sys$output "ACULOGIN.COM failed. ACUSTART.COM not run yet."
$       exit
$l_regname_ok:
$       'regname' :== $ ACU_ACUSYS:'regname'.EXE
$       ACU*M :== $ ACU_ACUSYS:'regname'.EXE
$	FED :== "@ACU_ACUSYS:FORMEDIT"
$       Set message sys$message:tpumsg ! ensure TPU gives sensible exit messages
$
$       ACU_EDIT :== EDIT/TPU          ! editor used to edit procedures etc
$       if decw then ACU_EDIT :== EDIT/TPU/DISPLAY=DECWINDOWS
$       ACU_BROWSE :== EDIT/TPU/READ   ! editor used to browse reports etc
$       if decw then ACU_BROWSE :== EDIT/TPU/READ/DISPLAY=DECWINDOWS
$!
$       DEFINE ACU_COLOUR_FILE  DECW$USER_DEFAULTS:DECW$SM_COLOR.DAT
$!
$       DEFINE REGIS TT
$       DEFINE ZETA  TT
$       DEFINE HPGL  TT
$!
$       DEFINE ACU_LOGIN OK
$exit

    Hello,
    
    	I doubt that your pb comes from that line :
    >>$       @acu_disk:[acusys]ADD_LOGICAL -
                    LNM$FILE_DEV LNM$PROCESS_DIRECTORY LNM$ACU_TABLE

    	What this procedure should do ? Does it redefine the logical
    name LNM$FILE_DEV to point to a new search list containing
    LNM$ACU_TABLE ? 
    	Don't forget that LNM$FILE_DEV must point to :
    		LNM$PROCESS
    		LNM$JOB
    		LNM$GROUP
    		LNM$SYSTEM
    AND         DECW$LOGICAL_NAMES 
    	if your procedure redefines LNM$FILE_DEV and forgets the 
    		DECW$LOGICAL_NAMES table, Fileview won't start.
    
    So your new LNM$FILE_DEV logical names must contain :
    		LNM$PROCESS
    		LNM$JOB
    		LNM$GROUP
    		LNM$SYSTEM
                DECW$LOGICAL_NAMES 
    	        LNM$ACU_TABLE
    
    					Hope this help,
    					Dung HOANG