| Yes there is a limit on "0=" task names. As I recal it is either
12 or 15 characters. Its in the guide to networking somewhere.
Still, thats not many characters, ".COM" is the default so you can
save 4 characters there. I would recomend something like:
"0=SHOW_ME_ymdhsss"
Where:
y = Decimal year number (ie. "1"-"9")
m = Hex representation of the month number (ie. "1"-"C")
d = Alphanumeric representation of the day number ("0"-"9","A"-"Z")
h = Alphanumeric repr. of the hour of the day ("0"-"9","A"-"Z")
sss = 3 character Hex repr. of the second in the hour.
Coding this should be a trip.
-- Barry
|
| Barry,
RE .1
Thanks for the info, it was very helpful and solved the problem. Here is
an extract of what I have done so far based on your ideas:
.
.
.
$ ! Makes unique time stamp that is easy to read and sorted in a directory
$ ! listing from oldest to newest.
$
$ time_stamp = F$EXTRACT( 2, 2, F$CVTIME(,,"YEAR") ) + -
F$CVTIME(,,"MONTH") + -
F$CVTIME(,,"DAY") + "_" + -
F$CVTIME(,,"HOUR") + -
F$CVTIME(,,"MINUTE") + -
F$CVTIME(,,"SECOND") + "_" + -
F$CVTIME(,,"HUNDREDTH")
.
.
.
$ !
$ ! Task names are limited to 12 characters and default to .COM filetype.
$ ! Reduce the time stamp from 16 to 12 characters by removing the 2
$ ! underscores and converting the 2-character month and hour fields to
$ ! 1-character letter fields.
$ !
$ time_stamp = time_stamp - "_" - "_" ! Remove underscores.
$ time_years = F$EXTRACT(0, 2, time_stamp) ! Extract year.
$ time_month = F$EXTRACT(2, 2, time_stamp) ! Extract month.
$ time_days = F$EXTRACT(4, 2, time_stamp) ! Extract days.
$ time_hours = F$EXTRACT(6, 2, time_stamp) ! Extract hours.
$ time_rest = F$EXTRACT(8, 6, time_stamp) ! Extract rest of it.
$ !
$ ! Convert number fields to letter fields using ASCII conversion.
$ !
$ month_alpha[0,8] = 64 + time_month ! 1 - 12 --> A - L.
$ hours_alpha[0,8] = 64 + time_hours ! 1 - 24 --> A - X.
$ !
$ ! Build new unique 12 character name.
$ !
$ task_name = time_years + month_alpha + time_days + -
hours_alpha + time_rest
$ !
$ ! Transfer the file to the remote node and execute the commands as
$ ! a network task.
$ !
$ COPY/LOG 'com_filename' 'node_name'""::'task_name'.COM
$ TYPE/OUTPUT='out_filename' 'node_name'""::"0=''task_name'"
$
.
.
.
Mark Gillis,
|