Conference 7.286::home_work

2052.0. "Directory searching batch procedure" by EPOCH::JOHNSON (Where the hell is Kyzyl?) Fri Mar 30 1990 11:19

This procedure has saved me *so* much time that I thought it might be useful to
others, especially in the context of a large conference like this:

A very powerful feature of VAXnotes is the ability to do DIR/TITLE, DIR/KEY,
and sometimes DIR/AUTHOR.  But this takes time.

I have it done in batch by having the attached SEARCHNOTES.COM file in my
directory and typing something like

          @searchnotes serena::home_work title "deck/patio/pressure"

A batch job is submitted for each of the items in the list (three, in this
case) and the results (if any) are VAXmailed to me.

There may be better ways to do it, but at least this works for me.

Pete
---------------------------------- CUT HERE -----------------------------------
$	conference = "''p1'"
$	switch = "''p2'"
$	target_list = "''p3'"
$	if "''p1'" .eqs. "" .or. -
		"''p2'" .eqs. "" .or. -
		"''p3'" .eqs. "" then goto inform
$	set noon
$	pid = f$getjpi("","PID")
$	user = f$edit(f$getjpi("","USERNAME"),"TRIM")
$	element_number = 0
$ loop:
$	target == f$element(element_number,"/",target_list)
$	if target .eqs. "/" then goto done
$	filename = "''pid'" + "''element_number'"
$	open/write outfile 'filename.temp_com
$	write outfile "$set ver"
$	write outfile "$notes/nonotebook ''conference'"
$	write outfile "dir /''switch'=''target' 9999.*-1.*/out=''filename'.txt"
$	write outfile "$mail ''filename'.txt ''user'/subj=""''switch' search of ''conference' for ''target'"""
$	write outfile "$del/noconf ''filename'.txt;*,''filename'.temp_com;*"
$	close outfile
$	submit/noprint/nokeep 'filename.temp_com
$	element_number=element_number+1
$	goto loop
$ done:
$	exit
$ inform:
$	write sys$output "Usage is @searchnotes conference switch list..."
$	write sys$output "Try again..."
$	goto done
$!
$!          I used to tie up my terminal by going into a
$!          conference and doing a DIR/TITLE=mumbly (I rarely
$!          used the DIR/KEYWORD=mumbly because I have found
$!          that keywords are rarely properly maintained...). 
$!          This habit tied up my terminal, so I wrote a short
$!          procedure to do the same thing in batch.  Over the
$!          months, it has developed into this, which has
$!          saved me a lot of time and helped me find things
$!          in VAXnotes conferences.
$!
$!          Be sure to retain the "/" as the delimiter in
$!          target_list as it is used to detect the end of the
$!          list of strings-of-interest.
$!
$!          Pete PETERJ::Johnson